Household Survey Question

{*********************************************************************
 Module   : IncomeSurvey.BLA
 Overview :

    Sample datamodel for household survey of income stuff.

    This datamodel contains a household roster which consists
    of a table of demographic questions for each person. This
    is followed by a series of questions for each person in the
    household. The latter are set up as an array. The Parallel
    block setting will show the persons as separate tabs. To see
    the person names on the tabs you will need to adjust the Datamodel
    Properties Parallel Block settings to use the labels which are 
    set up for the purpose (name: aTabHeading[1], aTabHeading[2] etc).

    This datamodel includes a question that identifies the person
    who is to receive the income questions. The person number is passed
    into the block of person questions in order to control the logic. 

 Author   : fred.wensing@softscape.net.au

 Update History:
 Vsn   dd/mm/yyyy Person Change
 ----- ---------- ------ ------
 1.001 30/08/2010 Fred   -Initial version
*********************************************************************}

DATAMODEL MySurvey "Income survey"

PRIMARY
    CaseID

{Parallel block setting - adds a tab for each person}    
PARALLEL
    Person    

{Type definitions used in the datamodel}
TYPE
    TPersons   = 1..10
    TName      = STRING[20]
    TNameArray = ARRAY[1..10] OF STRING[20]
    Tgender    = (Male, Female)
    TAge       = 0..120
    TYesNo     = (Yes (1) "Yes", No (5) "No")
    TContinue  = (Continue "Press [1] to continue")
    TIncSource = (Wages, Interest, Rent, Dividends, Other)

{Block for case identification}    
BLOCK BCaseID
  FIELDS
    Case_Number "Enter the case number (1000 to 9999)"
        / "Case number"
        : 1000..9999
ENDBLOCK    

{Block of person demographic details}
BLOCK BDemographic
  PARAMETERS
    pPersonNumber : TPersons  
  FIELDS
    Name "What is the ^aFirstNext person's name?" 
        / "Name"
        : TName 
    Gender "Is that person male or female?"
        / "Gender"
        : Tgender
    Age "How old is that person?"
        / "Age"
        : TAge               
  AUXFIELDS
    aFirstNext : STRING[20]
  RULES
    IF pPersonNumber=1 THEN
        aFirstNext := 'first'
    ELSE
        aFirstNext := 'next'
    ENDIF
    Name
    Gender
    Age        
ENDBLOCK

{Household roster - table of up to 10 persons}
TABLE BHousehold
  PARAMETERS
    pPersons : TPersons  
  FIELDS
    Demographic : ARRAY [1..10] OF BDemographic
  LOCALS
    X : INTEGER
  RULES
    FOR X:=1 TO 10 DO
        IF X<=pPersons THEN
            Demographic[X](X)  
        ENDIF
    ENDDO
ENDTABLE

{Survey questions for each person}
BLOCK BPerson
  PARAMETERS
    pNumber : TPersons
    pName : TName
    pGender : Tgender
    pIncomePsn : TPersons
  FIELDS
    Working "Does ^aName do any work in a job, business or farm?"
        / "Working"
        : TYesNo
    WorkKind "What kind of work does ^aHeShe do?"
        / "Kind"
        : STRING[50]
    Income_Source "What sources of income does this household have?"
        / "Income sources"
        :  SET OF TIncSource
    Income_Amount "What is the total annual income of this household?"
        / "Total income"
        : -999999..999999  
  AUXFIELDS
    aName : TName
    aHeShe : STRING[10]
  RULES
    {Define fill texts for the questions}
    aName := pName
    IF pGender=Male THEN
        aHeShe:='he'
    ELSEIF pGender=Female THEN
        aHeShe:='she'
    ENDIF
    {Ask the work questions}
    Working
    IF Working=Yes THEN
        WorkKind
    ENDIF
    {Only ask income questions of the person whose
     pNumber matches the pIncomePsn}
    IF pNumber=pIncomePsn THEN
        Income_Source
        Income_Amount
    ENDIF 
  LAYOUT
    BEFORE Working NEWPAGE         
ENDBLOCK

{Top level fields - control of survey}
FIELDS
    CaseID : BCaseID
    Num_Persons "How many persons live in this household?"
        / "Number"
        : TPersons
    Household : BHousehold
    HHEndPoint "Interviewer: This is the end of the household roster section"
        / "End point"
        : TContinue
    IncomePerson "Which person can answer the income questions?"
        / "Income person"
        : (Person1 "^aNameList[1]"
          ,Person2 "^aNameList[2]"
          ,Person3 "^aNameList[3]"
          ,Person4 "^aNameList[4]"
          ,Person5 "^aNameList[5]"
          ,Person6 "^aNameList[6]"
          ,Person7 "^aNameList[7]"
          ,Person8 "^aNameList[8]"
          ,Person9 "^aNameList[9]"
          ,Person10 "^aNameList[10]"
          )  
    Person : ARRAY [1..10] OF BPerson
AUXFIELDS
    aTabHeading  "Text for tab label" : ARRAY [1..10] OF STRING[40]
    aNameList    "List of person names" : TNameArray
    aIncomePsn   "Person number for income questions" : TPersons
LOCALS
    X : INTEGER
RULES
    {Number of persons in household}
    Num_Persons
    {Ask the household roster}
    Household (Num_Persons)
    {End point for household roster}
    HHEndPoint 
    {Fill the array of names for the income person question}
    FOR X:=1 TO 10 DO
        aNameList[X]:=Household.Demographic[X].Name
    ENDDO
    {ask the income person question}
    IncomePerson
    {set the income person number}
    aIncomePsn:=ORD(IncomePerson)
    {continue}
    IF HHEndPoint = Continue THEN
        {ask questions of each person}
        FOR X:=1 TO 10 DO
            IF Household.Demographic[X].Name<>EMPTY THEN
                {set the field used to put labels into the parallel tabs}
                aTabHeading[X] := Household.Demographic[X].Name
                {add a * for the person who is to receive income questions}
                IF X=aIncomePsn THEN
                    aTabHeading[X]:=aTabHeading[X]+' *'
                ENDIF    
                {ask the person questions}
                Person[X](X,Household.Demographic[X].Name,Household.Demographic[X].gender,aIncomePsn)
            ENDIF      
        ENDDO
    ENDIF
ENDMODEL